[iOS底层]-alloc和init底层逻辑

alloc流程分析

源码分析alloc流程

  • 下载objc4源码,我们就可以看到alloc方法的实现了。
+ (id)alloc {
return _objc_rootAlloc(self);
}
  • 接着跳转到_objc_rootAlloc
id
_objc_rootAlloc(Class cls)
{
return callAlloc(cls, false/*checkNil*/, true/*allocWithZone*/);
}
  • callAlloc源码实现
static ALWAYS_INLINE id
callAlloc(Class cls, bool checkNil, bool allocWithZone=false)
{
#if __OBJC2__
if (slowpath(checkNil && !cls)) return nil;
if (fastpath(!cls->ISA()->hasCustomAWZ())) {
return _objc_rootAllocWithZone(cls, nil);
}
#endif

// No shortcuts available.
if (allocWithZone) {
return ((id(*)(id, SEL, struct _NSZone *))objc_msgSend)(cls, @selector(allocWithZone:), nil);
}
return ((id(*)(id, SEL))objc_msgSend)(cls, @selector(alloc));
}

slowpath & fastpath 的作用是进行编译器优化。

#define fastpath(x) (__builtin_expect(bool(x), 1))
#define slowpath(x) (__builtin_expect(bool(x), 0))

__builtin_expect(bool(x), 1): 表示x的值为真的可能性更大。
__builtin_expect(bool(x), 0): 表示x的值为假的可能性更大。

if (slowpath(checkNil && !cls)) //等价于 if(checkNil && !cls)
if (fastpath(checkNil && !cls)) //也等价于 if(checkNil && !cls)

使用fastpath表示执行if后面的语句机会更大,slowpath执行else后面的语句机会更大。通过这种方式,编译器在编译过程中,会把可能性更大的代码紧跟前面的代码,从而减少指令跳转带来的性能上的下降。

  • _objc_rootAllocWithZone源码实现:
NEVER_INLINE
id
_objc_rootAllocWithZone(Class cls, malloc_zone_t *zone __unused)
{
// allocWithZone under __OBJC2__ ignores the zone parameter
return _class_createInstanceFromZone(cls, 0, nil, OBJECT_CONSTRUCT_CALL_BADALLOC);
}
  • 最后跳转到_class_createInstanceFromZone方法,在这个方法里面进行空间大小的计算和开辟内存空间,以及把开辟出来的空间跟类绑定在一起。
static ALWAYS_INLINE id
_class_createInstanceFromZone(Class cls, size_t extraBytes, void *zone,
int construct_flags = OBJECT_CONSTRUCT_NONE,
bool cxxConstruct = true,
size_t *outAllocatedSize = nil)
{
ASSERT(cls->isRealized());

// Read class's info bits all at once for performance
bool hasCxxCtor = cxxConstruct && cls->hasCxxCtor();
bool hasCxxDtor = cls->hasCxxDtor();
bool fast = cls->canAllocNonpointer();
size_t size;

// 计算需要开辟的内存空间大小
size = cls->instanceSize(extraBytes);
if (outAllocatedSize) *outAllocatedSize = size;

id obj;
if (zone) {
obj = (id)malloc_zone_calloc((malloc_zone_t *)zone, 1, size);
} else {
// alloc 开辟内存的地方
obj = (id)calloc(1, size);
}
if (slowpath(!obj)) {
if (construct_flags & OBJECT_CONSTRUCT_CALL_BADALLOC) {
return _objc_callBadAllocHandler(cls);
}
return nil;
}

if (!zone && fast) {
obj->initInstanceIsa(cls, hasCxxDtor);
} else {
// Use raw pointer isa on the assumption that they might be
// doing something weird with the zone or RR.
obj->initIsa(cls);
}

if (fastpath(!hasCxxCtor)) {
return obj;
}

construct_flags |= OBJECT_CONSTRUCT_FREE_ONFAILURE;
return object_cxxConstructFromClass(obj, cls, construct_flags);
}
  1. size = cls->instanceSize(extraBytes); 先计算出需要开辟多少内存空间
  2. obj = (id)calloc(1, size);向系统申请开辟内存,返回内存地址指针
  3. obj->initInstanceIsa(cls, hasCxxDtor);把地址指针关联到对应的类

alloc流程图

init源码分析

通过objc4源码,我们可以看到init的实例方法

- (id)init {
return _objc_rootInit(self);
}

// 跳转至_objc_rootInit源码
id
_objc_rootInit(id obj)
{
// In practice, it will be hard to rely on this function.
// Many classes do not properly chain -init calls.
return obj;
}

我们可以看到init只是把obj自己返回出去了,增加init是为了提供构造方法的入口